/*
 * Copyright 2019 ConsenSys AG.
 *
 * Licensed under the Apache License, Version 2.0 (the "License"); you may not use this file except in compliance with
 * the License. You may obtain a copy of the License at
 *
 * http://www.apache.org/licenses/LICENSE-2.0
 *
 * Unless required by applicable law or agreed to in writing, software distributed under the License is distributed on
 * an "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the License for the
 * specific language governing permissions and limitations under the License.
 */

dependencies {
  implementation project(':crypto')

  testImplementation project(':acceptance-tests:dsl')
  testImplementation project(':besu')
  testImplementation project(':config')
  testImplementation project(':consensus:clique')
  testImplementation project(':enclave')
  testImplementation project(':ethereum:api')
  testImplementation project(':ethereum:core')
  testImplementation project(path: ':ethereum:core', configuration: 'testSupportArtifacts')
  testImplementation project(':ethereum:permissioning')
  testImplementation project(':ethereum:rlp')
  testImplementation project(':plugin-api')
  testImplementation project(':privacy-contracts')
  testImplementation project(':testutil')
  testImplementation project(':util')

  testImplementation 'com.github.tomakehurst:wiremock-jre8-standalone'
  testImplementation 'commons-io:commons-io'
  testImplementation 'junit:junit'
  testImplementation 'net.consensys:orion'
  testImplementation 'org.apache.commons:commons-compress'
  testImplementation 'org.apache.tuweni:crypto'
  testImplementation 'org.assertj:assertj-core'
  testImplementation 'org.awaitility:awaitility'
  testImplementation 'org.web3j:abi'
  testImplementation 'org.web3j:besu'
  testImplementation 'tech.pegasys.ethsigner.internal:core'
  testImplementation 'tech.pegasys.ethsigner.internal:file-based'
}

test.enabled = false

sourceSets {
  test {
    resources {
      srcDirs "${rootDir}/besu/build/libs"
    }
  }
}

processTestResources.dependsOn(':besu:testJar')

task acceptanceTest(type: Test) {
  inputs.property "integration.date", LocalTime.now() // so it runs at every invocation

  dependsOn(rootProject.installDist)
  setSystemProperties(test.getSystemProperties())
  systemProperty 'acctests.runBesuAsProcess', 'true'
  systemProperty 'java.security.properties', "${buildDir}/resources/test/acceptanceTesting.security"
  mustRunAfter rootProject.subprojects*.test
  description = 'Runs Besu acceptance tests.'
  group = 'verification'

  jvmArgs "-XX:ErrorFile=${buildDir}/jvmErrorLogs/java_err_pid%p.log"

  testLogging {
    exceptionFormat = 'full'
    showStackTraces = true
    showStandardStreams = Boolean.getBoolean('acctests.showStandardStreams')
    showExceptions = true
    showCauses = true
  }

  doFirst {
    mkdir "${buildDir}/jvmErrorLogs"
  }
}